**********
* Copyright Intusoft 1994-1997
* All Rights Reserved
**********
*SRC=LM555;LM555;Timers;National;Behavioral <2kHz
*SYM=LM555
*
* This version of the LM555 will operate into the low khz (2kHz)
* region in the astable mode.
*
.SUBCKT LM555 2     3   4     5     6      7       8
*Connections  Trig. Out Reset Ctrl. Thres. Dischg. VCC
*Generic 555 Timer Chip Model
R1 8 5 5K
R2 5 9 5K
R3 9 0 5K
M1 0 3 7 7 PCHAN1 L=12.5U W=12.5U ;OFF
.MODEL PCHAN1 PMOS (LEVEL=1 VTO=-.6 KP=370.7M GAMMA=.46
+ PHI=.75 LAMBDA=2.08M RD=8M RS=8M IS=250F PB=.8 MJ=.46
+ CBD=45.9P CBS=83P CGSO=57N CGDO=37.5N CGBO=100N)
X2 6 5 10 8 COMP
X3 9 2 11 8 COMP
X4 11 10 3 12 8 SR
RESET 8 4 10G
MRESET 0 4 3 7 PCHAN L=12.5U W=12.5U ;OFF
.MODEL PCHAN PMOS (LEVEL=1 VTO=-.6 KP=378.7M GAMMA=.46
+ PHI=.75 LAMBDA=2.08M RD=8M RS=8M IS=250F PB=.8 MJ=.46
+ CBD=45.9P CBS=83P CGSO=57N CGDO=37.5N CGBO=100N)
.ENDS
*
*** Subcircuit SR BEGINS ***
*
.SUBCKT SR   1   2     3 4    5
*Connections Set Reset Q Qbar Power
X1 2 4 3 5 NOR
X2 3 1 4 5 NOR
.ENDS
*
*** Subcircuit NOR BEGINS ***
*
.SUBCKT NOR  1   2   3   5
*Connections In1 In2 Out Power
*THIS POWER SUPPLY POWERS THE WHOLE T555
M1 6 2 5 5 PCHANR L=12.5U W=50U 
M2 3 1 6 6 PCHANR L=12.5U W=50U ;OFF
M3 3 1 0 0 NCHANR L=12.5U W=12.5U ;OFF
M4 3 2 0 0 NCHANR L=12.5U W=12.5U 
.MODEL PCHANR PMOS (LEVEL=1 VTO=-.6 KP=361.2M GAMMA=.6868
+ PHI=.75 LAMBDA=2.08M RD=8M RS=8M IS=150F PB=.8 MJ=.46
+ CBD=45.9P CBS=83P CGSO=57N CGDO=37.5N CGBO=100N)
.MODEL NCHANR NMOS (LEVEL=1 VTO=.5 KP=361.2M GAMMA=.791
+ PHI=.55 LAMBDA=2.08M RD=8M RS=8M IS=150F PB=.8 MJ=.46
+ CBD=45.9P CBS=83P CGSO=57N CGDO=37.5N CGBO=100N)
.ENDS
*
***  Subcircuit COMP BEGINS  ***
*
.SUBCKT COMP 1   2   3   7
*Connection  In+ In- Out Timer_Supply_Voltage
R1CMP 1 2 1000G
RGND 2 0 100G
E1CMP 4 0 1 2 1000
R3CMP 4 3 100MEG
R4CMP 3 0 100MEG
*This voltage sets the upper limit on the output of 
*the comparator equal to the supply of the timer.
E1CLMP 5 0 POLY(1) 7 0 .8 1
D1CLMP 0 6 DIODE 
*This voltage sets the lower limit on the output of 
*the comparitor to zero volts
V2CLMP 6 3 DC -.8
D2CLMP 3 5 DIODE
.MODEL DIODE D
*(CJO=20P RS=1M)
.ENDS 
**********
*SRC=UA555;UA555;Timers;Fairchild;Transistor
*SYM=LM555
.SUBCKT UA555  32 30 19 23 33 1  21 
*              TR O  R  F  TH D  V  
*
* Taken from the Fairchild data book (1982) page 9-3
*SYM=UA555
*DWG=C:\SPICE\555\UA555.DWG
Q4 25 2 3 QP
Q5 0 6 3 QP
Q6 6 6 8 QP
R1 9 21 4.7K
R2 3 21 830
R3 8 21 4.7K
Q7 2 33 5 QN
Q8 2 5 17 QN
Q9 6 4 17 QN
Q10 6 23 4 QN
Q11 12 20 10 QP
R4 10 21 1K
Q12 22 11 12 QP
Q13 14 13 12 QP
Q14 0 32 11 QP
Q15 14 18 13 QP
R5 14 0 100K
R6 22 0 100K
R7 17 0 10K
Q16 1 15 0 QN
Q17 15 19 31 QP
R8 18 23 5K
R9 18 0 5K
R10 21 23 5K
Q18 27 20 21 QP
Q19 20 20 21 QP
R11 20 31 5K
D1 31 24 DA
Q20 24 25 0 QN
Q21 25 22 0 QN
Q22 27 24 0 QN
R12 25 27 4.7K
R13 21 29 6.8K
Q23 21 29 28 QN
Q24 29 27 16 QN
Q25 30 26 0 QN
Q26 21 28 30 QN
D2 30 29 DA
R14 16 15 100
R15 16 26 220
R16 16 0 4.7K
R17 28 30 3.9K
Q3 2 2 9 QP
.MODEL DA D (RS=40 IS=1.0E-14 CJO=1PF)
.MODEL QP PNP (BF=20 BR=0.02 RC=4 RB=25 IS=1.0E-14 VA=50 NE=2)  
+ CJE=12.4P VJE=1.1 MJE=.5 CJC=4.02P VJC=.3 MJC=.3 TF=229P TR=159N)
.MODEL QN NPN (IS=5.07F NF=1 BF=100 VAF=161 IKF=30M ISE=3.9P NE=2       
+ BR=4 NR=1 VAR=16 IKR=45M RE=1.03 RB=4.12 RC=.412 XTB=1.5      
+ CJE=12.4P VJE=1.1 MJE=.5 CJC=4.02P VJC=.3 MJC=.3 TF=229P TR=959P)
.ENDS