Fifth-Order Chebyshev Filter Function

*
* First-Order Chebyshev Filter Function Format
*
*                     w0
* TF(s) = K * ------------------
*              an * s + bN * w0
*
* Second-Order Chebyshev Filter Function Format
*
*                     w0^2
* TF(s) = -----------------------------
*         s^2 + aN * w0 * s + bN * w0^2
*

.param K  = 1/8.1408    $ gain
.param w0 = 62832       $ pole angular frequency
.param a1 = 1           $ s-multiplier a constant 1
.param b1 = 0.2895      $ s-multiplier b constant 1
.param a2 = 0.4684      $ s-multiplier a constant 2
.param b2 = 0.4293      $ s-multiplier b constant 2
.param a3 = 0.1789      $ s-multiplier a constant 3
.param b3 = 0.9883      $ s-multiplier b constant 3

** Circuit Description **
* input signal
Vin 1 0 AC 1V
* a cascade of biquads forming a 5th-order Chebyshev Filter Function
* 1st biquad
R1 1 0 100Meg
* E1 2 0 Laplace {V(1)} = { (6.2832e+4/8.1408)/(s+0.2895*6.2832e+4) }
AE1 1 2 filter1
.model filter1 s_xfer(gain=K
+                     num_coeff=[w0]
+                     den_coeff=[a1 {b1 * w0}]
+                     int_ic=[0 0])
* 2nd biquad
R2 2 0 100Meg
* E2 3 0 Laplace {V(2)} = { (6.2832e+4*6.2832e+4)/(s*s+0.4684*6.2832e+4*s+0.4293*6.2832e+4*6.2832e+4) }
AE2 2 3 filter2
.model filter2 s_xfer(gain=1
+                     num_coeff=[w0^2]
+                     den_coeff=[1 {a2 * w0} {b2 * w0^2}]
+                     int_ic=[0 0])
* 3rd biquad
R3 3 0 100Meg
* E3 4 0 Laplace {V(3)} = { (6.2832e+4*6.2832e+4)/(s*s+0.1789*6.2832e+4*s+0.9883*6.2832e+4*6.2832e+4) }
AE3 3 4 filter3
.model filter3 s_xfer(gain=1
+                     num_coeff=[w0^2]
+                     den_coeff=[1 {a3 * w0} {b3 * w0^2}]
+                     int_ic=[0 0])
* output
Rout 4 0 1k
** Analysis Requests **
.AC LIN 100 1Hz 20kHz
** Output Requests **
.PLOT AC VdB(4) cph(v(4))
.probe
.end