Fifth-Order Chebyshev Filter Circuit

** Circuit Description **

* op-amp subcircuit
.subckt ideal_opamp 1 2 3
* connections:      | | |
*              output | |
*             +ve input |
*               -ve input           
Eopamp 1 0 2 3 1e6
Iopen1 2 0 0A      ; redundant connection made at +ve input terminal
Iopen2 3 0 0A      ; redundant connection made at -ve input terminal
.ends ideal_opamp

** Main Circuit **
* input signal source
Vi 1 0 DC 0V AC 1V
* first biquad stage (Wo=41.17k rad/s  Q=1.4)
X_A1_1 5 2 4 ideal_opamp
X_A2_1 3 6 4 ideal_opamp
R1_1 5 6 10k
R2_1 4 5 10k
R3_1 3 4 10k
C4_1 2 3 2.43nF
R5_1 1 2 10k
C6_1 6 0 2.43nF
R6_1 6 0 14k
X_A3_1 7 6 7 ideal_opamp
* second biquad stage (Wo=62.46k rad/s  Q=5.56)
X_A1_2 11 8 10 ideal_opamp
X_A2_2 9 12 10 ideal_opamp
R1_2 11 12 10k
R2_2 10 11 10k
R3_2  9 10 10k
C4_2  8  9 1.6nF
R5_2  7  8 10k
C6_2 12  0 1.6nF
R6_2 12  0 55.6k
X_A3_2 13 12 13 ideal_opamp
* first-order stage
X_A1_3 15 0 14 ideal_opamp
R1_3 13 14 10k
R2_3 14 15 10k
C1_3 14 15 5.5nF
** Analysis Requests **
.AC LIN 100 1Hz 20kHz
** Output Requests **
.PLOT AC VdB(15) cph(v(15))
.probe
.end