A Simple Operational Amplifier

** Circuit Description **
* power supplies
Vcc 4 0 DC +15V
Vee 5 0 DC -15V
* differential-mode signal level
Vd 101 0 DC 0V
Rd 101 0 1
EVp 1 100 101 0 +0.5
EVm 2 100 101 0 -0.5
* common-mode signal level
Vcm 100 0 DC 0V
* 1st stage
R1 4 7 20k
R2 4 8 20k
Q1 7 1 6 npn_transistor
Q2 8 2 6 npn_transistor
Q3 6 9 5 npn_transistor
* 2nd stage
R3 4 11 3k
Q4 4 7 10 npn_transistor
Q5 11 8 10 npn_transistor
Q6 10 9 5 npn_transistor 4
* 3rd or output stage
R4 4 12 2.3k
Q7 13 11 12 pnp_transistor
R5 13 5 15.7k
Q8 4 13 3 npn_transistor
R6 3 5 3k
* biasing stage
Rb 0 9 28.6k
Q9 9 9 5 npn_transistor
* transistor model statements
.model npn_transistor npn ( Is=18fA Bf=100 VAf=100V )
.model pnp_transistor pnp ( Is=18fA Bf=100 VAf=100V )
** Analysis Requests **
* compute DC operating point using the following initial guesses 
.OP
.NODESET V(3)=0V V(6)=-0.7V V(7)=+10V V(8)=+10V V(9)=-14.3V V(10)=+9.3V
+        V(11)=+12V V(12)=+12.7V V(13)=+0.7V
* compute large-signal differential-input transfer characteristics of amplifier
.DC Vd -15V +15V 100mV
** Output Requests **
.PLOT DC V(3)
.probe
.end