Funções de onda do átomo de H

Prof. jose antonio diaz navas, no Mathematica Stack Exchange

a0=Quantity["BohrRadius"]/Quantity["Meters"]

ψ[{n_,l_,m_},{r_,θ_,ϕ_}]:=With[{ρ=2 r/(n a0)},Sqrt[(2/(n a0))^3 (n-l-1)!/(2 n (n+l)!)] Exp[-ρ/2] ρ^l LaguerreL[n-l-1,2 l+1,ρ] SphericalHarmonicY[l,m,θ,ϕ]]

n=2;l=0;m=0

f=TransformedField["Spherical"->"Cartesian",ψ[{n,l,m},{r,θ,ϕ}],{r,θ,ϕ}->{x,y,z}];

DensityPlot3D[(Abs@f)^2,{x,-20 a0,20 a0},{y,-20 a0,20 a0},{z,-20 a0,20 a0},RegionFunction->Function[{x,y,z},x<0||y>0],ColorFunction->Hue,ColorFunctionScaling->True,ViewPoint->{1.3,-2.4,1.},FaceGrids->{{-1,0,0},{0,1,0},{0,0,-1}},Ticks->Table[{{-20 a0,"-20 a0"},{-10 a0,"-10 a0"},{0,"0"},{10 a0,"10 a0"},{20 a0,"20 a0"}},{i,3}]]

Integrate[ψ[{n,l,m},{r,θ,ϕ}]*Conjugate[ψ[{n,l,m},{r,θ,ϕ}]]r^2 Sin[θ],{r,0,Infinity},{θ,0,Pi},{ϕ,0,2Pi}]

Integrate[Abs[ψ[{n,l,m},{r,θ,ϕ}] ]^2  r^2 Sin[θ],{r,0,Infinity},{θ,0,Pi},{ϕ,0,2Pi}]

Manipulate interface

Manipulate[Module[{f,feLabel,feLabel2,feLabelm,feLabel2m},f=TransformedField["Spherical"->"Cartesian",Abs[ψ[{n,l,m},{r,θ,ϕ}]]^2,{r,θ,ϕ}->{x,y,z}];
feLabel=StringJoin[ToString[fe]," a0"];
feLabel2=StringJoin[ToString[fe/2]," a0"];
feLabelm=StringJoin["-",ToString[fe]," a0"];
feLabel2m=StringJoin["-",ToString[fe/2]," a0"];
DensityPlot3D[f,{x,-fe a0,fe a0},{y,-fe a0,fe a0},{z,-fe a0,fe a0},RegionFunction->Function[{x,y,z},x<0||y>0],ColorFunction->Hue,ColorFunctionScaling->True,ViewPoint->{1.3,-2.4,1.},FaceGrids->{{-1,0,0},{0,1,0},{0,0,-1}},Ticks->Table[{{-fe a0,feLabelm},{-fe a0/2,feLabel2m},{0,"0"},{fe a0/2,feLabel2},{fe a0,feLabel}},{i,3}]]],{{n,1},1,5,1},{{l,0},0,n-1,1},{{m,0},0,l,1},{{fe,20},2,40,2}]