****************************************************************************************************************
***************************************** AULA 02 - MONITORIA STATA ********************************************
****************************************************************************************************************

*************************************** ANÁLISE DE REGRESSÃO SIMPLES *******************************************
****************************************************************************************************************

// Comandos práticos antes da abertura da base
clear all 
cap log close
set dp comma

* mudando o diretório
cd "C:\Users\Matheus\Desktop"

* abrindo o log
log using "aula2.log", append
  
* abrindo a base de dados (MEDICAL EXPENDITURE PANEL SURVEY)
use mus03data.dta, clear

////// ANÁLISE DESCRITIVA DE BASE DE DADOS

describe totexp ltotexp suppins phylim actlim totchr age female income
summarize totexp ltotexp suppins phylim actlim totchr age female income

* tabelas estatísticas
tab totchr
tab totchr female

* tabelas com estatísticas específicas (e não freqüências relativas)
tab totchr female, nofreq column

* ln do salário
gen lincome = ln(income)


////// ANÁLISE DE REGRESSÃO SIMPLES

* Estudando a correlação (duas a duas) das possíveis variáveis do modelo
correlate ltotexp suppins phylim actlim totchr age female lincome
pwcorr ltotexp suppins phylim actlim totchr age female lincome, star(0.01)

* Estimando o modelo
regress ltotexp suppins phylim actlim totchr age female lincome

* Teste Breusch-Pagan-Godfrey. Hipótese nula é homocedasticidade
estat hettest  

* O valor da probabilidade igual a zero (ou chi-quadrado alto) indica problemas de heterocedasticidade
* Para corrigir este problema, podemos acrecentar uma opção 'vce(robust)'
regress ltotexp suppins phylim actlim totchr age female lincome, vce(robust)

* Outro teste que podemos operar para testar a homocedasticidade é o teste de White. Se rodarmos a 
* regressão com o comando 'quietly' (ou 'qui') na frente, o Stata opera a regressão, mas não solta os resultados
quietly regress ltotexp suppins phylim actlim totchr age female lincome

* Para instalar o teste de  White, usamos os comandos:
ssc install whitetst

* Finalmente rodamos o teste White com o comando:
whitetst

* Da mesma forma, o teste de White tem hipótese nula de homocedasticidade. Como o p-valor foi 
* praticamente zero, temos indício de heterocedasticidade na regressão. Corrigimos então com 'vce(robust)'


* FAZENDO TESTES DE HIPÓTESES (com o teste Wald)

* Podemos usar o comando 'test' para testarmos alguma hipótese específica no Stata, após rodarmos
* uma regressão:
qui regress ltotexp suppins phylim actlim totchr age female lincome
test phylim = actlim

* Como a Probabilidade (0.4726) é maior que o valor de corte de 5% (0.05), então não podemos rejeitar a 
* hipótese nula de que os parâmetros são iguais (não são estatisticamente distintos)

* Outro  exemplo de teste é testar para a significância conjunta de alguns parâmetros:
test phylim actlim totchr

* Aqui, como a probabilidade é zero (e portanto menor que 5%), aceitamos a hipótese de que os parâmetros
* são estatisticamente diferentes de zero


* OUTROS COMANDOS

* Muitas vezes é útil salvarmos os coeficientes de diversas regressões e compararmos todos numa tabela.
* Para tal, usamos o comando 'estimates store'

quietly regress ltotexp suppins phylim actlim totchr age female lincome
estimates store Reg01

quietly regress ltotexp suppins phylim actlim totchr age female lincome educyr
estimates store Reg02

* Para mostrarmos numa tabela, usamos 'estimates table'
estimates table Reg01 Reg02, b stats(N r2 F ll) b(%7.2f) star(0.10 0.05 0.01)


* fechando o log
log close