using "types";

FlowSheet Pei_Ying_Lin_2020

	
	PARAMETERS
	
	qGmax as coefficient (Unit = 'mol/mol/h');
	ks1 as conc_mol; 
	pHLL as ph;
	pHUL as ph;
	Yxs as coefficient (Unit = 'mol/mol');
	kd1 as frequency;
	fHAc as coefficient (Unit = 'mol/mol');
	fHBu as coefficient (Unit = 'mol/mol');
	fHEt as coefficient (Unit = 'mol/mol');
	fH2 as coefficient (Unit = 'mol/mol');
	SHmd as conc_mol;
	Kaac as conc_mol;
	Kabu as conc_mol;
	V as volume;
	Vg as volume;
	Scat as conc_mol;
	San as conc_mol;
	R as coefficient (Unit = 'bar*l/(mol*K)');
	T as temperature;
	P as pressure;

	VARIABLES

	SGli as conc_mol;
	SHAc as conc_mol;
	SHBu as conc_mol;
	SHEt as conc_mol;
	SH2 as conc_mol;
	X1 as conc_mol;
	IpH as fraction;
	pH as ph;
	SAcm as conc_mol;
	SBum as conc_mol;
	SHm as conc_mol;
	V_H2 as volume;
	

	EQUATIONS
	
	"Biological Phase" 

	
	
	diff(SGli)=             -qGmax*(SGli/(ks1+SGli))*X1*IpH;
	diff(SHAc)= (1-Yxs)*fHAc*qGmax*(SGli/(ks1+SGli))*X1*IpH;
	diff(SHBu)= (1-Yxs)*fHBu*qGmax*(SGli/(ks1+SGli))*X1*IpH;
	diff(SHEt)= (1-Yxs)*fHEt*qGmax*(SGli/(ks1+SGli))*X1*IpH;
	diff(SH2) =  (1-Yxs)*fH2*qGmax*(SGli/(ks1+SGli))*X1*IpH;
	diff(X1)  =          Yxs*qGmax*(SGli/(ks1+SGli))*X1*IpH;
	
	
	"liquid Phase"
	
	
	pH=-log(SHm/SHmd);
	if pH < pHUL
	then IpH = (1+2*10^(0.5*(pHLL-pHUL)))/(1+10^(pH-pHUL)+10^(pHLL-pH));
	else IpH = 1;	
	end
	
	#SAcm=SHAc*Kaac/(Kaac+SHm);
	#SBum=SHBu*Kabu/(Kabu+SHm);
	SHm+Scat=SAcm+SBum+San;
	SHAc=SHm*SAcm/Kaac;
	SHBu=SHm*SBum/Kabu;
		

	"gas Phase"
	
	
	V_H2=SH2*V*R*T/P;
	
	
	SET
	
	qGmax = 1.03*'mol/mol/h';
	ks1 = 0.0026*'mol/l'; 
	pHLL = 4;   
	pHUL = 5.5;
	Yxs = 0.229*'mol/mol';
	fHAc = 0.464*'mol/mol';
	fHBu = 0.83*'mol/mol';
	fHEt = 0.0*'mol/mol';
	fH2 = 3.66*'mol/mol';
	SHmd = 1*'mol/l';
	Kaac = 0.000017378*'mol/l';
	Kabu = 0.000014454*'mol/l';
	V = 0.08*'l';
	Vg = 0.04*'l';
	Scat = 0.04*'mol/l';
	San = 0.02*'mol/l';
	R = 0.083145*'bar*l/(mol*K)';
	T = 298.15*'K';
	P = 1*'bar';

	INITIAL
	
	SGli = 0.017*'mol/l';
	X1 = 0.002*'mol/l';
	#IpH = 1;
	#pH = 7;
	SHAc = 0.00001*'mol/l';
	SHBu = 0.00001*'mol/l';
	SHEt = 0.00001*'mol/l';
	SHm = 0.000000158*'mol/l';
	#SAcm = 0.000000001*'mol/l';
	#SBum = 0.000000001*'mol/l';
	SH2 = 0.0000000001*'mol/l';
	
	
	OPTIONS

	TimeStart = 0;
	TimeStep = 0.5;
	TimeEnd = 30;
	TimeUnit = 'h';
end