cd "C:\Users\leand\Google Drive\Matérias_doc_2019_02\Monitoria Eco II\Aula 05"


use "Aula 05 - base.dta", clear


* Tabela 01

sum sexo cor idade pref_fam casalsf rendfampc freq_esc anest idade2 c_ocup trab proc_trab id1trab migrante rm ar urb if pia == 1 & pea == 1


* Tabela 02
global x "idade idade2 id1trab anest sexo pref_fam cor trab proc_trab rm ar urb casalsf rendfampc freq_esc"

probit migrante $x if pia == 1 & pea == 1

predict p_migrante, pr


* Tabela 03
margins, dydx($x) atmeans vsquish


* Tabela 04
global x2 "idade id1trab anest sexo cor rm ar urb casalsf rendfampc freq_esc"
mlogit c_ocup $x2 p_migrante if pia == 1 & pea == 1, base(2)


* Tabela 05
margins, dydx($x2 p_migrante) atmeans predict(outcome(1))
margins, dydx($x2 p_migrante) atmeans predict(outcome(2))
margins, dydx($x2 p_migrante) atmeans predict(outcome(3))



* O artigo termina aqui. Entretanto, vou apresentar a seguir o Modelo de auto seleção de Heckman
* propriamente dito.

* A pergunta que quero responder é se existe a questão de auto seleção de migrantes no mercado de trabalho
* e se isso influencia os salários.

use "Aula 05 - base.dta", clear
global x "idade idade2 id1trab anest sexo pref_fam cor trab proc_trab rm ar urb casalsf freq_esc"
global x2 "idade id1trab anest sexo cor rm ar urb casalsf freq_esc"

* travando a amostra para indivíduos que tenham informações de todas as variáveis
keep if migrante != . & renda != .  & idade != . & idade2 != . & id1trab != . & anest != . & sexo != . & pref_fam != . & cor != . & trab != . & proc_trab != . & rm != . & ar != . & urb != . & casalsf != . & freq_esc != .

* mantendo apenas observações que estão em idade ativa e são pea
keep if pia == 1 & pea == 1



* 1º estágio: estimação da probabilidade de ser migrante e cálculo da razão inversa de Mills
probit migrante $x

predict phat, xb


//Calculando razão inversa de Mills
gen mills = exp(-.5*(phat^2)) / (sqrt(2*_pi)*normprob(phat))


//Cálculo alternativo da razão inversa de Mills
gen double cdf=normal(phat)
gen double pdf=normalden(phat)

gen double mills2 = pdf/cdf


//Cálculo alternativo da razão inversa de Mills
gen phat1 = -phat
gen phi = (1/sqrt(2*_pi))*exp(-((phat1^2)/2))
gen capphi = normal(phat1)
gen mills3 = phi/(1-capphi)


* 2º estágio: estimação de MQO do nível do salário
reg renda $x2 mills


* Observe que a estimativa da inversa de Mills é estatisticamente significativa
* O que indica a presença de auto seleção de migrantes e o processo de determinação
* dos salários.


// Comando alternativo para Heckman two step
heckman renda $x2, select(migrante = $x) twostep


* Observação: especificamente nesses resultados, o Heckman two step feito na mão
* e o realizado via comando deu resultados marginalmente diferentes.
* Ainda não descobri o motivo, mas vou continuar verificando.