TITLE 'DQL - Análise';
DATA aula6;
INPUT linha coluna trat$ prod @@;
DATALINES;
1 1 D 432 2 1 C 724
1 2 A 518 2 2 E 478
1 3 B 458 2 3 A 524
1 4 C 583 2 4 B 550
1 5 E 331 2 5 D 400
3 1 E 489 4 1 B 494
3 2 B 384 4 2 D 500
3 3 C 556 4 3 E 313
3 4 D 297 4 4 A 486
3 5 A 420 4 5 C 501
5 1 A 515
5 2 C 660
5 3 D 438
5 4 E 394
5 5 B 318
;
PROC SORT DATA=aula6; 
 BY trat; 
RUN;


TITLE 'Análise de variância e obtenção dos resíduos';
PROC GLM DATA=aula6;
CLASS linha coluna trat;
MODEL prod=linha coluna trat/SS3;
OUTPUT OUT=residuos PREDICTED=y_est RESIDUAL=res_ord STUDENT=res_Stud;
RUN;


TITLE 'Análise exploratória dos resíduos';
PROC PLOT DATA=residuos;
PLOT res_Stud*trat="*"/vpos=20;
PLOT res_Stud*y_est="*"/vpos=20;
RUN;


TITLE 'Verificação da Normalidade dos resíduos Normal-plot e Teste de Shapiro-Wilk';
PROC UNIVARIATE DATA=residuos NORMAL;
VAR res_Stud; 
qqplot/NORMAL (MU=0 SIGMA=1 COLOR=RED);
RUN;


TITLE 'Teste de não-aditividade de Tukey (1 gl)';
PROC GLM DATA=aula6;
CLASS linha coluna trat;
MODEL prod=linha coluna trat/SS3;
OUTPUT OUT=AD PREDICTED=y_est RESIDUAL=res_ord STUDENT=res_Stud;
RUN;
DATA AD; SET AD;
 pred2=y_est*y_est;
RUN;
/*ATENÇÃO USA SOMA DE QUADRADOS TIPO I - SS1 NO COMANDO MODEL*/
PROC GLM DATA=AD;
CLASS linha coluna trat;
MODEL prod=linha coluna trat pred2/SS1;
RUN;

TITLE 'Transformação de Box-Cox';
ODS GRAPHICS ON;
PROC TRANSREG DATA=aula6 plots(UNPACK);
MODEL BOXCOX(prod/CONVENIENT LAMBDA=-2to 2 BY 0.05) = CLASS(trat linha coluna);
ods select BoxCoxLogLikePlot;
RUN;
ODS GRAPHICS OFF;


TITLE 'Teste de Tukey';
PROC GLM DATA=aula6;
CLASS linha coluna trat;
MODEL prod = linha coluna trat/SS3;
* Teste de Tukey;
MEANS trat/TUKEY;
RUN;
ODS HTML CLOSE;