/*MONITORIA ECONOMETRIA II - MONITOR: FELIPE COSTA*/
/*PROFESSOR: DANIEL SANTOS*/

/*               MODELOS DE RESPOSTA BINÁRIA OU ESCOLHA DISCRETA               */

clear all
set more off

cd "D:\MEGA\Monitorias\REC2312 - Econometria II\Probit e Logit"
*Vamos usar os dados do 4º trimestre de 2014 da PNADC:
use pnadc_20144.dta, clear

*Manter na base aberta apenas as variáveis que serão utilizadas:
keep VD4016 V2009 VD3001 V2007 V2010 VD4002 V2005 V1023

*Estar ocupado:
rename VD4002 ocup
recode ocup 1=0
recode ocup 2=1

*Se o indivíduo é ou não chefe de família
gen chefe = .
recode chefe .=0 if V2005!=.
recode chefe 0=1 if V2005==1

*Se o indivíduo é ou não filho
gen filho = .
recode filho .=0 if V2005!=.
recode filho 0=1 if V2005==4 | V2005==5 | V2005==6

*Se indivíduo pertence/mora ou não em uma região metropolitana
gen RM = 0
recode RM 0=1 if V1023==1 | V1023==2

*Idade:
rename V2009 idade

*Nível de instrução:
*** Se o indivíduo possui ou não fundamental completo
gen efund = . 
recode efund .=1 if VD3001==3
recode efund .=0 if VD3001!=.

*** Se o indivíduo possui ou não ensino médio completo
gen emedio = . 
recode emedio .=1 if VD3001==5
recode emedio .=0 if VD3001!=.

*** Se o indivíduo possui ou não ensino superior completo 
gen esup = .
recode esup .=1 if VD3001==7
recode esup .=0 if VD3001!=.

*Dummy de gênero:
rename V2007 mulher
recode mulher 1=0
recode mulher 2=1

*Dummy para indivíduo negro:
gen negro = .
recode negro .=1 if V2010==2
recode negro .=0 if V2010!=.

***ESTIMAÇÕES***

/*Vamos estimar como as variáveis podem explicar o caso em que o indivíduo está empregado ou não, sendo que a interpretação será em relação à probabilidade do
evento ocorrer*/

*Modelo de Probabilidade Linear (MPL):
reg ocup i.chefe i.filho i.efund i.emedio i.esup i.mulher#i.negro idade i.RM 
*Vamos salvar os valores ajustados de y com o nome de "ocup_hat":
predict ocup_hat, xb

*Faça um histograma dos valores preditos pelo MPL e veja que existem diversos valores que são inferiores a zero e maiores que um:
histogram ocup_hap /*Criando o histograma da variável ocup_hat criada acima!*/

*Probit:
probit ocup i.chefe i.filho i.efund i.emedio i.esup i.mulher#i.negro idade i.RM

*Logit:
logit ocup i.chefe i.filho i.efund i.emedio i.esup i.mulher#i.negro idade i.RM

***EFEITOS MARGINAIS***

/*Lembre-se que, nas estimações de modelos Probit e Logit, os estimadores dados pelos coeficientes dos regressores do modelo acima não são os verdadeiros
efeitos marginais. O efeito marginal sobre uma variável será dado pelo produto do estimador do coeficiente e da função densidade de probabilidade (f.d.p.), que é
função de XB, ou seja, o efeito marginal depende dos valores de X considerados pela estimação.*/

/*Um fato interessante é que podemos calcular efeitos marginais para indivíduos com características específicas. Por exemplo, vamos considerar o efeito de ter
como grau mais alto o ensino superior, primeiro para uma mulher negra de 30 anos que mora em uma RM e que é chefe de família:*/

quietly probit ocup i.chefe i.filho i.efund i.emedio i.esup i.mulher#i.negro idade i.RM
margins, dydx(esup) at(chefe=1 filho=0 efund=0 emedio=0 esup=1 idade=30 RM=1 mulher=1 negro=1)

***Note que o dydx indica exatamente que queremos o efeito marginal de x sobre y (se quiser o efeito marginal de todas as variáveis, é só usar dydx(*)).

/*Agora vamos olhar o efeito marginal de ter ensino superior para um indivíduo com as mesmas características, porém do sexo masculino.*/
margins, dydx(esup) at(chefe=1 filho=0 efund=0 emedio=0 esup=1 idade=30 RM=1 mulher=0 negro=1)

***IMPORTANTE: Tente interpretar o que significa a diferença entre os efeitos marginais calculados! Se quiser, envie-me sua resposta por e-mail para discutirmos.

/*Como o efeito marginal depende do valor das variáveis explicativas, quando se busca um "efeito médio" é bastante comum usar a média das variáveis e colocar
dentro da f.d.p. E como fazer isso? Simples, basta usar a opção "atmeas" ao invés de "at"*/
margins, dydx(esup) atmeans

/*Um exemplo final: Para calcular os efeitos marginais de todas as variáveis explicativas, só que queremos saber o efeito marginal "médio" para o chefe de famí-
lia, ou seja, a única especificidade que queremos olhar e "chefe"=1 e para as demais variáveis seus valores médios, basta combinar o "at" com o "atmeans":*/
margins, dydx(*) at(chefe=1) atmeans

/*Obs: O comando "margins" também pode ser usado com o Logit. O uso do Probit ou do Logit é de escolha do econometrista, porém em ambos os parâmetros não pos-
suem interpretação, por isso encontrar os efeitos marginais é tão importante para ambos.