/*MONITORIA ECONOMETRIA II - MONITOR: FELIPE COSTA*/
/*PROFESSOR: DANIEL SANTOS*/

/*               MODELOS DE DADOS EMPILHADOS E EM PAINEL               */

clear all
set more off

cd "D:\MEGA\Monitorias\REC2312 - Econometria II\Painel\Microdados PNADC"
use pnadc_append.dta, clear

*Manter na base aberta apenas as variáveis que serão utilizadas:
keep VD4016 V2009 VD3001 V2007 V2010 Ano domic pes domic2 pes2 tri time indiv

*Salário
rename VD4016 sal
gen ln_sal = ln(sal)
tabstat sal, s(mean sd min p10 p50 p90 p95 max)

*Idade:
rename V2009 idade

*Nível de instrução:
*** Se o nível mais alto de educação alcançado foi ensino fundamental completo:
gen efund = . 
recode efund .=1 if VD3001==3
recode efund .=0 if VD3001!=.

*** Se o nível mais alto de educação alcançado foi ensino médio completo:
gen emedio = . 
recode emedio .=1 if VD3001==5
recode emedio .=0 if VD3001!=.

*** Se o nível mais alto de educação alcançado foi ensino superior completo:
gen esup = .
recode esup .=1 if VD3001==7
recode esup .=0 if VD3001!=.

*Dummy de gênero:
rename V2007 mulher
recode mulher 1=0
recode mulher 2=1

*Dummy para indivíduo negro:
gen negro = .
recode negro .=1 if V2010==2
recode negro .=0 if V2010!=.

*Criando dummies para cada ano:
tab Ano, gen(dum_ano)
rename dum_ano1 d2012
rename dum_ano2 d2013
rename dum_ano3 d2014


***POOLED OLS ou MQO Empilhados***
*Esse é caso em que não temos, de fato, dados em painel. Então a regressão é feita como temos feitos nas últimas monitorias.
*Obs: O objetivo é capturar os efeitos do tempo sobre as variáveis. Por isso usamos dummies temporais.
reg ln_sal d2013 d2014 idade c.idade#1.d2013 c.idade#1.d2014 efund 1.efund#1.d2013 1.efund#1.d2014 emedio 1.emedio#1.d2013 1.emedio#1.d2014 esup 1.esup#1.d2013 1.esup#1.d2014 mulher 1.mulher#1.d2013 1.mulher#1.d2014

***PAINEL***
*Definindo o painel:
xtset indiv time

/* IMPORTANTE: As variáveis dummy para os níveis de educação só foram inseridas nas regressões abaixo pois existem na base indivíduos cuja escolaridade mais al-
ta se modifica (por exemplo, em um trimestre a escolaridade mais alta era o médio completo, e no trimestre seguinte é o superior). Dummies como as de cor e sexo
não são inseridas, pois elas devem desaparecer quando estimamos por PD ou EF uma vez que são constantes. */

/*Criando variáveis que podem nos auxiliar a utilizar as dummies deixadas de fora. Aqui não se usam as interações com "#", pois o operador de primeira diferença
"D" não lida bem com tais interações:*/

gen idade2 = idade*idade
gen idademul = idade*mulher
gen idadenegro = idade*negro

*PRIMEIRAS DIFERENÇAS:
reg D.(ln_sal d2013 d2014 idade idade2 idademul idadenegro efund emedio esup), noconstant rob

*EFEITOS FIXOS:
xtreg ln_sal d2013 d2014 idade idade2 idademul idadenegro efund emedio esup, fe rob

*EFEITOS ALEATÓRIOS:
xtreg ln_sal d2013 d2014 idade idade2 idademul idadenegro efund emedio esup, re rob


***TESTE DE HAUSMAN***
/*Obs: O teste de Hausman não pode ser utilizado em estimações que consideram heretocedasticidade (o que foi feito nas estimações acima com o comando "rob",
que indica estimação robusta à heterocedasticidade: */
*O comando "quietly" serve para que o Stata faça as estimações sem mostrar os seus resultados.

quietly xtreg ln_sal d2013 d2014 idade idade2 idademul idadenegro efund emedio esup, fe
estimates store EF
quietly xtreg ln_sal d2013 d2014 idade idade2 idademul idadenegro efund emedio esup, re
estimates store EA

hausman EA EF