/*MONITORIA ECONOMETRIA II - MONITOR: FELIPE COSTA*/
/*PROFESSOR: DANIEL SANTOS*/

*Definindo diretório no seu computador
cd "F:\Monitorias Econometria II\Variáveis_Instrumentais"

*Vamos salvar um documento ".log" para guardar o histórico de saídas do Stata.
*1) Tenha certeza que não exista um arquivo .log já aberto no seu Stata:
capture log close /*"capture" serve para que se o comando leve a erro, este seja ignorado e o do-file continue a rodar*/

*2) Começando um arquivo .log:
log using "variaveis_instrumentais_testes.log", replace
*A opção replace servirá para que, caso já exista um arquivo com esse nome no mesmo diretório, ele seja substuído pelo novo.

clear all
set more off

*Vamos usar os dados do exemplo 15.5 do livro do Wooldridge para podermos mostrar os comandos de teste.
*Abrindo a base online:
use http://fmwww.bc.edu/ec-p/data/wooldridge/mroz, clear

ivregress 2sls lwage (educ = motheduc fatheduc) exper expersq

***TESTE DE WU-HAUSMAN***
*Vamos testar a endogeneidade da variável "educ".
reg educ expersq motheduc fatheduc
	predict u_wh, res /*"res" significa que estamos salvando os resíduos da regressão*/
*Atente-se que u_wh é apenas o nome dado para a variável que contém os resíduos. Fica a seu gosto como ela vai ser nomeada.

reg lwage educ exper expersq u_wh
*Se rejeitar a hipótese nula de que o coeficiente de u_wh é zero, é indicativo de que a variável "educ" é de fato endógena.


***TESTE DE DURBIN-WU-HAUSMAN***
*Outra forma de testar a nossa hipótese de regressor endógeno.
reg lwage educ exper expersq
	estimates store MQO

ivregress 2sls lwage (educ = motheduc fatheduc) exper expersq
	estimates store MQ2E

hausman MQ2E MQO /*Primeiro colocar o consistente (MQ2E) e depois o mais eficiente (MQO)*/

*Podemos, por sua vez, com apenas uma linha obter ambos os testes, usando "estat endogenous"
ivregress 2sls lwage (educ = motheduc fatheduc) exper expersq
	estat endogenous
*Lembre-se que a melhor forma sempre é deixar que o Stata faça o teste de maneira automática, então use este último comando para um resultado mais correto.

***TESTE J ou TESTE DE SARGAN***
*Vamos então testar a exogeneidade dos instrumentos escolhidos:
ivregress 2sls lwage (educ = motheduc fatheduc) exper expersq
	estat overid

log close