/*MONITORIA ECONOMETRIA II - MONITOR: FELIPE COSTA*/
/*PROFESSOR: DANIEL SANTOS*/

/*EXEMPLOS DE ESTIMAÇÃO POR VI E MQ2E - J. M. WOOLDRIDGE*/

*Para consultar todos os exemplos contidos no livro:
*fmwww.bc.edu/gstat/examples/wooldridge/wooldridge.html

*Definindo diretório no seu computador
cd "F:\Monitorias Econometria II\Variáveis_Instrumentais"

*Vamos salvar um documento ".log" para guardar o histórico de saídas do Stata.
*1) Tenha certeza que não exista um arquivo .log já aberto no seu Stata:
capture log close /*"capture" serve para que se o comando leve a erro, este seja ignorado e o do-file continue a rodar*/

*2) Começando um arquivo .log:
log using "variaveis_instrumentais_wooldridge.log", replace
*A opção replace servirá para que, caso já exista um arquivo com esse nome no mesmo diretório, ele seja substuído pelo novo.

clear all
set more off

***EXEMPLO 15.4 (IV Estimator)***
*Utilizando a proximidade da universidade como VI para educação:
*Abrindo a base disponível online:
use http://fmwww.bc.edu/ec-p/data/wooldridge/card, clear

*Fazendo a regressão por MQO:
reg lwage educ exper expersq black smsa south
*Cuidado com a interpretação dos coeficientes agora que a variável depende é ln(salário), conforme discutimos em aula!

*Vamos então usar a variável "nearc4", que é uma dummy igual a 1 caso o indivíduo tenha crescido próximo a uma "universidade de quatro anos", como um instrumento para educação:
ivreg lwage (educ=nearc4) exper expersq black smsa south, first

*ou a versão mais atual do ivreg (mas que não é usada nos exemplos do livro):
ivregress 2sls lwage (educ=nearc4) exper expersq black smsa south, first

*Você pode usar um comando mais atual para tal estimativa que é o ivreg2, mas ele precisa ser instalado no Stata.
capture ssc install ivreg2 /*se o comando já foi instalado, está linha é desnecessária*/
ivreg2 lwage (educ=nearc4) exper expersq black smsa south, first
*Note que ele é uma boa alternativa, uma vez que sua saída oferece mais informações do que o comando padrão, bem como resultados mais precisos.


***EXEMPLO 15.5 (MQ2E ou 2SLS, na sigla em inglês)***
*Utilizando educação do pai e da mãe como instrumento para educação do indivíduo:
*Abrindo a base online:
use http://fmwww.bc.edu/ec-p/data/wooldridge/mroz, clear /*A opção "clear" é necessária porque estamos abrindo uma nova base quando outra já estava aberta*/

*Fazendo a regressão por MQO:
reg lwage educ exper expersq
estimates store MQO /*Para salvar nossas estimativas da última regressão feita*/

*Primeiro vamos testar a "força" dos instrumentos, ou seja, se cov(endogena,instrumento) é diferente de zero.
reg educ exper expersq motheduc fatheduc
test motheduc fathedu /*Teste F com Hipótese Nula de que ambos os coeficientes são iguais a zero*/

*Vamos fazer o estimador de dois estágios "manualmente", mas lembre-se que é apenas um exercício didático! (como discutimos em sala)
*PRIMEIRO ESTÁGIO:
reg educ exper expersq motheduc fatheduc
predict educ_hat, xb /*Guardando o valor ajustado da variável dependente, neste caso "educ"*/

*SEGUNDO ESTÁGIO:
reg lwage educ_hat exper expersq
estimates store MQ2E_manual

*Agora vamos o modo CORRETO de fazendo a estimação pelo Stata:
ivreg lwage (educ = motheduc fatheduc) exper expersq
estimates store MQ2E

*Pode-se corrigir a matriz de covariâncias para que seja robusta a problemas de heterocedasticidade.
ivreg lwage (educ = motheduc fatheduc) exper expersq, robust

*Versão mais nova do comando:
ivregress 2sls lwage (educ = motheduc fatheduc) exper expersq
estimates store MQ2E_new
ivregress 2sls lwage (educ = motheduc fatheduc) exper expersq, robust

*Fazendo uma tabela para comparar os resultados!
*Primeiro, é necessário instalar os pacotes de comandos:
capture ssc install estout

*Fazendo a tabela
esttab MQO MQ2E_manual MQ2E MQ2E_new

*Fechando o arquivo log:
log close