ODS HTML;
DATA aveia;
INPUT Bloco$ Variedade$ Semente$ prod @@;
CARDS;
I A1 B1 42.9 I A1 B2 53.8
I A1 B3 49.5 I A1 B4 44.4
I A2 B1 53.3 I A2 B2 57.6
I A2 B3 59.8 I A2 B4 64.1
I A3 B1 62.3 I A3 B2 63.4
I A3 B3 64.5 I A3 B4 63.6
I A4 B1 75.4 I A4 B2 70.3
I A4 B3 68.8 I A4 B4 71.6
II A1 B1 41.6 II A1 B2 58.5
II A1 B3 53.8 II A1 B4 41.8
II A2 B1 69.6 II A2 B2 69.6
II A2 B3 65.8 II A2 B4 57.4
II A3 B1 58.5 II A3 B2 50.4
II A3 B3 46.1 II A3 B4 56.1
II A4 B1 65.6 II A4 B2 67.3
II A4 B3 65.3 II A4 B4 69.4
III A1 B1 28.9 III A1 B2 43.9
III A1 B3 40.7 III A1 B4 28.3
III A2 B1 45.4 III A2 B2 42.4
III A2 B3 41.4 III A2 B4 44.1
III A3 B1 44.6 III A3 B2 45
III A3 B3 62.6 III A3 B4 52.7
III A4 B1 54 III A4 B2 57.6
III A4 B3 45.6 III A4 B4 56.6
IV A1 B1 30.8 IV A1 B2 46.3
IV A1 B3 39.4 IV A1 B4 34.7
IV A2 B1 35.1 IV A2 B2 51.9
IV A2 B3 45.4 IV A2 B4 51.6
IV A3 B1 50.3 IV A3 B2 46.7
IV A3 B3 50.3 IV A3 B4 51.8
IV A4 B1 52.7 IV A4 B2 58.5
IV A4 B3 51 IV A4 B4 47.4
;
PROC PRINT DATA=aveia;
TITLE 'Dados para verificação';
RUN;

/*ANÁLISE UTILIZANDO O PROC GLM PARA OBTER AS SOMAS DE QUADRADOS*/

PROC GLM DATA=AVEIA PLOTS(ONLY)=(DIAGNOSTICS); /*ANÁLISE GRAFICA DOS RESÍDUOS - Erro(b) da ANAVA */
TITLE 'ANAVA - PARCELA SUBDIVIDIDA';
TITLE2 'PELO PROC GLM';
CLASS Variedade Semente Bloco;
MODEL prod = Bloco Variedade Bloco*Variedade Semente Variedade*Semente/SS3;
/*Esse comando TEST especifica corretamente com qual resíduo(a ou b) deve ser feito o teste*/
/* para o tratamento de parcela (Variedades deve ser testada com o Erro(a)=Variedade*Bloco)*/
TEST H=Variedade E=Bloco*Variedade;
means Variedade/tukey e=Variedade*Bloco; /*apenas para indicação pois a interação foi significativa*/
means Semente/tukey; /*apenas para indicação pois a interação foi significativa*/
run;
PROC GLM DATA=AVEIA plots=none;
TITLE 'ANAVA - DESDOBRAMENTO T.SUBPARCELA (Sementes) EM CADA NÍVEL DE T.PARCELA (Variedade)';
title2 'Neste caso usa o Erro(b) da análise de variância, de forma adequada';
CLASS Variedade Semente Bloco;
MODEL prod = Bloco Variedade Variedade*Bloco Semente Variedade*Semente/ss3;
lsmeans Variedade*Semente/slice=Variedade;
run;
PROC GLM DATA=AVEIA plots=none;
TITLE 'ANAVA - DESDOBRAMENTO T.PARCELA (Variedade) EM CADA NÍVEL DE T.SUBPARCELA (Semente)';
Title2 'Neste caso deve-se usar o Erro composto = Erro(a) e Erro(b) da análise de variância';
Title3 'Desconsiderar o resultado do teste F (F Value e valor-p) na análise do desdobramento, está usando o Erro(b)';
CLASS Variedade Semente Bloco;
MODEL prod = Bloco Variedade Variedade*Bloco Semente Variedade*Semente/ss3;
lsmeans Variedade*Semente/slice=Semente;
run;

/* ANÁLISE UTILIZANDO O PROC MIXED TESTE ADEQUADO USANDO OS GRAUS DE LIBERDADE POR SATTERTHWAITE*/
/* O PROC MIXED NÃO SOLTA AS SOMAS DE QUADRADOS*/

PROC MIXED PLOTS=none;
TITLE 'ANÁLISE PELO PROC MIXED';
TITLE2 'ANAVA - DESDOBRAMENTO T.SUBPARCELA (Sementes) EM CADA NÍVEL DE T.PARCELA (Variedade)';
CLASS Variedade Semente Bloco;
MODEL prod = Variedade Semente Variedade*Semente/ DDFM=SATTERTHWAITE; /*DDFM especifica o método de obtenção dos graus de liberdade no Erro composto*/
RANDOM Bloco Bloco*Variedade;
MEANS Semente/Tukey; /*Teste Tukey para o tratamento de Subparcela*/
MEANS Variedade/Tukey; /*Teste Tukey para o tratamento de Parcela*/
LSMEANS Variedade*Semente/slice=Variedade adjust=tukey pdiff=all;
store sasuser.letras;
RUN;
PROC PLM restore=sasuser.letras plots=none;
lsmeans Variedade*Semente / adjust=tukey;
slice Variedade*Semente / sliceby=Variedade lines adjust=tukey;
RUN;
PROC MIXED plots=none;
TITLE 'ANÁLISE PELO PROC MIXED';
TITLE2 'ANAVA - DESDOBRAMENTO T.PARCELA (Variedade) EM CADA NÍVEL DE T.SUBPARCELA (Semente)';
CLASS Variedade Semente Bloco;
MODEL prod = Variedade Semente Variedade*Semente/ DDFM=SATTERTHWAITE;
RANDOM Bloco Bloco*Variedade;
LSMEANS Variedade*Semente/slice=Semente adjust=tukey PDIFF=all;
store sasuser.letras;
RUN;
PROC PLM restore=sasuser.letras plots=none;
lsmeans Variedade*Semente / adjust=tukey;
slice Variedade*Semente / sliceby=Semente lines adjust=tukey;
RUN;
ODS HTML CLOSE;