options nodate nonumber ps=65 ls=78;
ods html;
data ms;
input Trat Irrig Calag prod;
datalines;
1 0 0 25
1 0 0 32
1 0 0 27
2 0 1 35
2 0 1 28
2 0 1 33
3 1 0 41
3 1 0 35
3 1 0 38
4 1 1 60
4 1 1 67
4 1 1 59
;
proc print;
title 'Dados para verificação';
run;
proc tabulate data=ms;
title ' Análise descritiva - Médias segundo a Irrigação e a Calagem';
class Irrig Calag;
var prod;
table Irrig,Calag*prod*mean;
run;
proc means noprint data=ms;
var prod;
by Irrig Calag;
output out=medias mean=media;
run;
symbol1 interpol=join
value=dot;
proc gplot data=medias;
title 'Gráfico de interação Calagem x Irrigação';
plot media*Calag=Irrig ;
run;
proc gplot data=medias;
title 'Gráfico de interação Irrigação x Calagem';
plot media*Irrig=Calag;
run;
quit;
proc glm data=ms;
title 'Análise de variância e resíduos';
class Irrig Calag;
model prod = Irrig Calag Irrig*Calag;
output out=residuos PREDICTED=pred
RESIDUAL=res_ord STUDENT=res_stud;
run;
proc print data=residuos;
title 'Exame dos resíduos';
run;
proc univariate data=residuos normal plot;
title 'Verificação da normalidade (teste Shapiro-Wilk), análise gráfica';
var res_stud; qqplot;
run;
goptions reset=all;
symbol1 value=dot;
proc gplot data=residuos;
title 'Análise gráfica dos resíduos';
plot res_stud*pred;
run;
proc glm data=ms;
title 'Análise de variância sem discriminar os
fatores e Teste de Tukey para médias de
tratamentos';
class trat;
model prod = trat /ss3;
means trat/Tukey;
run;
proc glm data=ms;
title 'Análise de variância discriminando
os fatores';
class Irrig Calag;
model prod = Irrig Calag Irrig*Calag/ss3;
run;
proc glm data=ms;
title 'Desdobramento Calagem dentro de cada
Irrigação';
class Irrig Calag;
model prod = Irrig Calag Irrig*Calag/ss3;
lsmeans Irrig*Calag/slice=Irrig
adjust=tukey
PDIFF=all;
store sasuser.letras;run;
proc PLM restore=sasuser.letras;
lsmeans Irrig*Calag / lines adjust=tukey;
slice Irrig*Calag / sliceby=Irrig lines
adjust=tukey;
run;
proc glm data=ms;
title 'Desdobramento Irrigação dentro de
cada nível de Calagem';
class Irrig Calag;
model prod = Irrig Calag Irrig*Calag/ss3;
lsmeans Irrig*Calag/slice=Calag
adjust=tukey
PDIFF=all;
store sasuser.letras;run;
proc PLM restore=sasuser.letras;
lsmeans Irrig*Calag / lines adjust=tukey;
slice Irrig*Calag / sliceby=Calag lines
adjust=tukey;
run;
ods html close;