ODS HTML;
/* CASUALIZAÇÃO DE UM EXPERIMENTO EM DBC */
TITLE1 'Delineamento Casualizado em Blocos';
TITLE2 'Programa para casualizar os Tratamentos as Parcelas';
PROC PLAN SEED=105;
FACTORS blocos=3 ORDERED parcelas=9 ORDERED;
TREATMENTS trat=9 RANDOM;
OUTPUT OUT=plano trat; 
RUN;
PROC PRINT DATA=plano; 
RUN;


/* ANÁLISE DE VARIÂNCIA, RESIDUOS E TESTE DE COMPARAÇÕES DE MÉDIAS DE UM DBC */
TITLE 'DBC - Análise';
DATA laranja;
INPUT bloco trat prod @@;
DATALINES;
1 1 145 1 2 200 1 3 183
1 4 190 1 5 180 1 6 130
1 7 206 1 8 250 1 9 164
2 1 155 2 2 190 2 3 186
2 4 175 2 5 160 2 6 160
2 7 165 2 8 271 2 9 190
3 1 166 3 2 190 3 3 208
3 4 186 3 5 156 3 6 130
3 7 170 3 8 230 3 9 193
;
PROC SORT DATA=laranja;
BY trat; 
RUN;
TITLE 'Análise de variância e obtenção dos resíduos';
PROC GLM DATA=laranja;
CLASS bloco trat;
MODEL prod=bloco trat/SS3;
OUTPUT OUT=residuos PREDICTED=y_est RESIDUAL=res_ord STUDENT=res_Stud;
RUN;

TITLE 'Análise exploratória dos resíduos';
PROC PLOT DATA=residuos;
PLOT res_Stud*trat="*"/vpos=20;
PLOT res_Stud*y_est="*"/vpos=20;
RUN;

TITLE 'Verificação da Normalidade dos resíduos Normal-plot e Teste de Shapiro-Wilk';
PROC UNIVARIATE DATA=residuos NORMAL;
VAR res_Stud;
qqplot/NORMAL(MU=0 SIGMA=1 COLOR=RED);
RUN;

TITLE 'Transformação de Box-Cox';
ods GRAPHICS ON;
PROC TRANSREG DATA=laranja plots(UNPACK); 
MODEL BOXCOX(prod/CONVENIENT LAMBDA=-2 to 2 BY 0.05) = CLASS(trat bloco);
ods select BoxCoxLogLikePlot;
RUN;
ods GRAPHICS OFF;

TITLE 'Teste de Tukey e Testes F e t para contrastes';
PROC GLM DATA=laranja;
CLASS bloco trat;
MODEL prod = bloco trat/SS3;
* Teste de Tukey;
MEANS trat/TUKEY;

* Testes F e t para contrastes;

CONTRAST "LIMÃO VERSUS DEMAIS" trat -1 2 2 -1 -1 -1 -1 -1 2;
CONTRAST "LIMÃO: RUGOSO VERSUS CRAVO" trat 0 1 1 0 0 0 0 0 -2;
CONTRAST "LIMÃO RUGOSO: NACIONAL VERSUS FLORIDA" trat 0 1 -1 0 0 0 0 0 0;
CONTRAST "TANGERINA VERSUS DEMAIS (QUE NÃO SÃO LIMÃO)" trat 1 0 0 1 -1 -1 1 -1 0;
CONTRAST "TANGERINA: (SUNKI E CLEÓPATRA) VERSUS CRAVO" trat 1 0 0 1 0 0 -2 0 0;
CONTRAST "TANGERINA: SUNKI VERSUS CLEÓPATRA" trat 1 0 0 -1 0 0 0 0 0;
CONTRAST "(CITRANGE E TRIFOLIATA) VERSUS LARANJA" trat 0 0 0 0 1 1 0 -2 0;
CONTRAST "CITRANGE VERSUS TRIFOLIATA" trat 0 0 0 0 1 -1 0 0 0;


/*OS COMANDOS ESTIMATE SÃO OS MESMOS DOS "CONTRAST"*/
ESTIMATE "LIMÃO VERSUS DEMAIS" trat -1 2 2 -1 -1 -1 -1 -1 2;
ESTIMATE "LIMÃO: RUGOSO VERSUS CRAVO" trat 0 1 1 0 0 0 0 0 -2;
ESTIMATE "LIMÃO RUGOSO: NACIONAL VERSUS FLORIDA" trat 0 1 -1 0 0 0 0 0 0;
ESTIMATE "TANGERINA VERSUS DEMAIS (QUE NÃO SÃO LIMÃO)" trat 1 0 0 1 -1 -1 1 -1 0;
ESTIMATE "TANGERINA: (SUNKI E CLEÓPATRA) VERSUS CRAVO" trat 1 0 0 1 0 0 -2 0 0;
ESTIMATE "TANGERINA: SUNKI VERSUS CLEÓPATRA" trat 1 0 0 -1 0 0 0 0 0;
ESTIMATE "(CITRANGE E TRIFOLIATA) VERSUS LARANJA" trat 0 0 0 0 1 1 0 -2 0;
ESTIMATE "CITRANGE VERSUS TRIFOLIATA" trat 0 0 0 0 1 -1 0 0 0;

RUN;
ODS HTML CLOSE;